From c4367035ec0638d5639157e98e6756d3779aeee5 Mon Sep 17 00:00:00 2001
From: Jacques Comeaux <jacquesrcomeaux@protonmail.com>
Date: Sat, 6 Dec 2025 16:40:13 -0600
Subject: Move FinMerge utilites

---
 FinMerge/Util.agda | 32 ++++++++++++++++++++++++++++++++
 1 file changed, 32 insertions(+)
 create mode 100644 FinMerge/Util.agda

(limited to 'FinMerge/Util.agda')

diff --git a/FinMerge/Util.agda b/FinMerge/Util.agda
new file mode 100644
index 0000000..6a7f7b4
--- /dev/null
+++ b/FinMerge/Util.agda
@@ -0,0 +1,32 @@
+{-# OPTIONS --without-K --safe #-}
+module FinMerge.Util where
+
+open import Data.Fin using (Fin; toℕ)
+open import Data.Nat using (ℕ; _≤_; _<_ ; z<s; s≤s)
+open import Data.Product using (_×_; _,_)
+open import Relation.Binary.PropositionalEquality using (_≡_; refl; cong)
+
+
+_<_≤_ : ℕ → ℕ → ℕ → Set
+_<_≤_ i j k = (i < j) × (j ≤ k)
+
+_<_<_ : ℕ → ℕ → ℕ → Set
+_<_<_ i j k = (i < j) × (j < k)
+
+toℕ< : {n : ℕ} → (i : Fin n) → toℕ i < n
+toℕ< Fin.zero = z<s
+toℕ< (Fin.suc i) = s≤s (toℕ< i)
+
+data Ordering {n : ℕ} : Fin n → Fin n → Set where
+  less : ∀ {i j} → toℕ i < toℕ j < n → Ordering i j
+  equal : ∀ {i j} → i ≡ j → Ordering i j
+  greater : ∀ {i j} → toℕ j < toℕ i < n → Ordering i j
+
+compare : ∀ {n : ℕ} (i j : Fin n) → Ordering i j
+compare Fin.zero Fin.zero = equal refl
+compare Fin.zero j@(Fin.suc _) = less (z<s , toℕ< j)
+compare i@(Fin.suc _) Fin.zero = greater (z<s , toℕ< i)
+compare (Fin.suc i) (Fin.suc j) with compare i j
+... | less (i<j , j<n) = less (s≤s i<j , s≤s j<n)
+... | equal i≡j = equal (cong Fin.suc i≡j)
+... | greater (j<i , i<n) = greater (s≤s j<i , s≤s i<n)
-- 
cgit v1.2.3